Ser Analista

Inicio › Guías › Guía · Excel

Guía · Excel

BUSCARV en Excel, con ejemplo

Qué hace, cómo se escribe cada parte y por qué a veces da #N/A. Con una tabla de equipos de la Copa.

1

Qué hace BUSCARV

BUSCARV busca un valor en la primera columna de una tabla y te devuelve un dato de otra columna de la misma fila. Es como buscar a alguien en una lista por su nombre y leer su teléfono. En Excel en inglés se llama VLOOKUP.

=BUSCARV(valor_buscado; tabla; columna; FALSO)

Según cómo esté configurado tu Excel, los argumentos se separan con ; o con ,. Si te da error de fórmula, probá con el otro.

2

La tabla de ejemplo

Tenemos los equipos de la Copa con su país y su ciudad, en A1:C6. Queremos saber de qué país es Tubarões do Recife sin buscarlo a ojo.

A · EquipoB · PaísC · Ciudad
1EquipoPaísCiudad
2Sportivo TacurúParaguayEncarnación
3Truenos de RosarioArgentinaRosario
4Tubarões do RecifeBrasilRecife
5Agaves de GuadalajaraMéxicoGuadalajara
6Gaviotas de MontevideoUruguayMontevideo
3

La fórmula, argumento por argumento

Se lee así: buscá el texto de E2, en la tabla A2:C6, devolveme la columna 2 y que la coincidencia sea exacta.

=BUSCARV("Tubarões do Recife"; A2:C6; 2; FALSO)
ArgumentoEn el ejemploQué significa
valor_buscado"Tubarões do Recife"Lo que buscás. Puede ser una celda, como E2.
tablaA2:C6Dónde buscar. La primera columna tiene que ser la del valor buscado.
columna2Qué columna devolver, contando desde la primera de la tabla (no desde la A).
FALSOFALSOCoincidencia exacta. Casi siempre va FALSO.

Resultado: Brasil.

4

Copiarla hacia abajo con $

Si la vas a copiar para varias filas, fijá la tabla con signos $. Si no, al copiarla el rango se corre una fila por vez y deja de encontrar los equipos de arriba.

=BUSCARV(E2; $A$2:$C$6; 3; FALSO)

Copiada en F2:F4 (columna 3 = ciudad)

E · ClubF · Ciudad
2Agaves de GuadalajaraGuadalajara
3Truenos de RosarioRosario
4Gaviotas de MontevideoMontevideo
5

Los errores más comunes

Cuando BUSCARV falla, casi siempre es por una de estas cosas. Revisalas en este orden.

  • #N/A: no encuentra el valorEl valor no está, o está escrito distinto: un espacio de más al final, una tilde, o un número guardado como texto. ESPACIOS() ayuda a limpiar los espacios.
  • Trae un dato equivocado sin dar errorTe olvidaste el FALSO del final. Sin él, BUSCARV hace una búsqueda aproximada y puede devolver la fila de otro equipo.
  • #¡REF!El número de columna es más grande que la cantidad de columnas de la tabla.
  • No puede buscar hacia la izquierdaBUSCARV solo busca en la primera columna y devuelve hacia la derecha. Para lo otro, usá BUSCARX o INDICE + COINCIDIR.
6

La alternativa moderna: BUSCARX

En Excel 365 y 2021 está BUSCARX (XLOOKUP): le decís dónde buscar y qué devolver por separado, busca exacto sin que se lo pidas y puede ir hacia la izquierda.

=BUSCARX(E2; A2:A6; B2:B6)

Si tu Excel no la tiene, BUSCARV sigue siendo la que más se pide en entrevistas y la que vas a ver en planillas viejas.

Ahora, practicalo

En la Copa Latinoamericana Excel tenés un nivel entero de BUSCARV y BUSCARX, con una planilla de verdad dentro del navegador y pistas de Datito. Gratis y sin crear cuenta.

¿Querés todos los ejercicios resueltos y explicados paso a paso, para repasar con calma? Ver los ebooks con ejercicios resueltos →

Otras guías